import java.time.*

def p = { println it }

// We'll start by getting the current time.
def now = Instant.now()
p(now)

// You can build a time instance by providing the
// year, month, day, etc. Times are always associated
// with a ZoneId, i.e. time zone.
def then = ZonedDateTime.of(2009, 11, 17, 20, 34, 58, 651387237, ZoneId.of("UTC"))
p(then)

// You can extract the various components of the time
// value as expected.
p(then.year)
p(then.month)
p(then.dayOfMonth)
p(then.hour)
p(then.minute)
p(then.second)
p(then.nano)
p(then.zone)

// The Monday-Sunday DayOfWeek is also available.
p(then.dayOfWeek)

// These methods compare two times, testing if the
// first occurs before, after, or at the same time
// as the second, respectively.
p(then.isBefore(now.atZone(ZoneId.of("UTC"))))
p(then.isAfter(now.atZone(ZoneId.of("UTC"))))
p(then.isEqual(now.atZone(ZoneId.of("UTC"))))

// The Duration class represents the interval between two times.
def diff = Duration.between(then.toInstant(), now)
p(diff)

// We can compute the length of the duration in
// various units.
p(diff.toHours())
p(diff.toMinutes())
p(diff.getSeconds())
p(diff.toNanos())

// You can use plus to advance a time by a given
// duration, or with a minus to move backwards by a
// duration.
p(then.plus(diff))
p(then.minus(diff))