using Dates

function main()
    # First we'll look at basic rate limiting. Suppose
    # we want to limit our handling of incoming requests.
    # We'll serve these requests off a channel of the
    # same name.
    requests = Channel{Int}(5)
    for i in 1:5
        put!(requests, i)
    end
    close(requests)

    # This limiter channel will receive a value
    # every 200 milliseconds. This is the regulator in
    # our rate limiting scheme.
    limiter = Channel{DateTime}(Inf)
    @async while true
        put!(limiter, now())
        sleep(0.2)
    end

    # By blocking on a receive from the limiter channel
    # before serving each request, we limit ourselves to
    # 1 request every 200 milliseconds.
    for req in requests
        take!(limiter)
        println("request ", req, " ", now())
    end

    # We may want to allow short bursts of requests in
    # our rate limiting scheme while preserving the
    # overall rate limit. We can accomplish this by
    # buffering our limiter channel. This burstyLimiter
    # channel will allow bursts of up to 3 events.
    burstyLimiter = Channel{DateTime}(3)

    # Fill up the channel to represent allowed bursting.
    for i in 1:3
        put!(burstyLimiter, now())
    end

    # Every 200 milliseconds we'll try to add a new
    # value to burstyLimiter, up to its limit of 3.
    @async while true
        put!(burstyLimiter, now())
        sleep(0.2)
    end

    # Now simulate 5 more incoming requests. The first
    # 3 of these will benefit from the burst capability
    # of burstyLimiter.
    burstyRequests = Channel{Int}(5)
    for i in 1:5
        put!(burstyRequests, i)
    end
    close(burstyRequests)
    for req in burstyRequests
        take!(burstyLimiter)
        println("request ", req, " ", now())
    end
end

main()